如何将DBMS_OUTPUT.PUT_LINE的输出重定向到文件？

我需要在pl / sql中调试以计算程序的时间，我想使用：

SELECT systimestamp FROM dual INTO time_db;
DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);

但我不明白输出的位置以及如何将其重定向到包含我想要收集的所有数据的日志文件？

已邀请:

10 个回复

布埃郝卞簿

DBMS_OUTPUT不是最好的调试工具，因为大多数环境本身不使用它。但是，如果要捕获DBMS_OUTPUT的输出，则只需使用DBMS_OUTPUT.get_line程序。这是一个小例子：

SQL> create directory tmp as '/tmp/';

Directory created

SQL> CREATE OR REPLACE PROCEDURE write_log AS
  2     l_line VARCHAR2(255);
  3     l_done NUMBER;
  4     l_file utl_file.file_type;
  5  BEGIN
  6     l_file := utl_file.fopen('TMP', 'foo.log', 'A');
  7     LOOP
  8        EXIT WHEN l_done = 1;
  9        dbms_output.get_line(l_line, l_done);
 10        utl_file.put_line(l_file, l_line);
 11     END LOOP;
 12     utl_file.fflush(l_file);
 13     utl_file.fclose(l_file);
 14  END write_log;
 15  /

Procedure created

SQL> BEGIN
  2     dbms_output.enable(100000);
  3     -- write something to DBMS_OUTPUT
  4     dbms_output.put_line('this is a test');
  5     -- write the content of the buffer to a file
  6     write_log;
  7  END;
  8  /

PL/SQL procedure successfully completed

SQL> host cat /tmp/foo.log

this is a test

磐剩

作为写入文件的替代方法，如何写入表？您可以调用自己的DEBUG.OUTPUT过程，而不是调用DBMS_OUTPUT.PUT_LINE：

procedure output (p_text varchar2) is
   pragma autonomous_transaction;
begin
   if g_debugging then
      insert into debug_messages (username, datetime, text)
      values (user, sysdate, p_text);
      commit;
   end if;
end;

使用自治事务允许您保留从回滚的事务（例如，在引发异常之后）产生的调试消息，如果您使用文件时会发生这种情况。 g_debugging布尔变量是一个包变量，可以默认为false，并在需要调试输出时设置为true。当然，您需要管理该表，以便它不会永远增长！一种方法是每晚/每周运行的作业并删除任何“旧”的调试消息。

鞘垒飘

使用 set serveroutput on; 例如：

set serveroutput on;

DECLARE
x NUMBER;
BEGIN
x := 72600;
dbms_output.put_line('The variable X = '); dbms_output.put_line(x);
END;

邵酮

如果您只是在SQL Plus中测试PL / SQL，可以将它指向如下文件：

spool output.txt
set serveroutput on

begin
  SELECT systimestamp FROM dual INTO time_db;
  DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);
end;
/

spool off

像Toad和SQL Developer这样的IDE可以通过其他方式捕获输出，但我不熟悉如何。

感秆暴壳

除了Tony的回答，如果你想找出你的PL / SQL程序花费时间的地方，还值得查看这部分Oracle PL / SQL文档。

磐去裸猜饲

使用UTL_FILE而不是DBMS_OUTPUT会将输出重定向到文件： http://oreilly.com/catalog/oraclebip/chapter/ch06.html

谷靛

作为旁注，请记住所有这些输出都是在服务器端生成的。使用DBMS_OUTPUT，文本在服务器中生成，同时执行查询并存储在缓冲区中。然后，当服务器完成查询数据检索时，它会重定向到您的客户端应用程序。也就是说，您只在查询结束时才会收到此信息。使用UTL_FILE，记录的所有信息都将存储在服务器的文件中。执行完成后，您必须导航到此文件才能获取信息。希望这可以帮助。

碧肮械淌设

它可以直接将文件写入托管数据库的数据库服务器，并且随着PL / SQL程序的执行而改变。这使用Oracle目录TMP_DIR;您必须声明它，并创建以下过程：

CREATE OR REPLACE PROCEDURE write_log(p_log varchar2)
  -- file mode; thisrequires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
  l_file utl_file.file_type;
BEGIN
  l_file := utl_file.fopen('TMP_DIR', 'my_output.log', 'A');
  utl_file.put_line(l_file, p_log);
  utl_file.fflush(l_file);
  utl_file.fclose(l_file);
END write_log;
/

以下是如何使用它： 1）从SQL * PLUS客户端启动它：

BEGIN
  write_log('this is a test');
  for i in 1..100 loop
    DBMS_LOCK.sleep(1);
    write_log('iter=' || i);
  end loop;
  write_log('test complete');
END;
/

2）在数据库服务器上，打开一个shell和 tail -f -n500 /directory/where/oracle/can/write/on/DB_server/my_output.log

悍蕾驮苇袜

一个旧线程，但还有另一种选择。从9i开始，您可以使用流水线表功能。首先，将类型创建为varchar表：

CREATE TYPE t_string_max IS TABLE OF VARCHAR2(32767);

其次，将代码包装在流水线函数声明中：

CREATE FUNCTION fn_foo (bar VARCHAR2) -- your params
  RETURN t_string_max PIPELINED IS 
  -- your vars
BEGIN
  -- your code
END;
/

将所有DBMS_OUTPUT.PUT_LINE全部替换为PIPE ROW。最后，这样称呼它：

SELECT * FROM TABLE(fn_foo('param'));

希望能帮助到你。

笛驮型迸

试试这个：

SELECT systimestamp INTO time_db FROM dual ;

DBMS_OUTPUT.PUT_LINE('time before procedure ' || time_db);

要回复问题请先登录或注册

如何将DBMS_OUTPUT.PUT_LINE的输出重定向到文件？

10 个回复

发起人

dbms_output

问题状态

如何将DBMS_OUTPUT.PUT_LINE的输出重定向到文件？

与内容相关的链接

10 个回复

发起人

dbms_output

问题状态